TITLE Styrene Inhalation Model, Reaction Form

PARAMETER
{
  BW = 0.3	(kg)
  QP = 5.74	(l/hr)
  QC = 5.74	(l/hr)
  VFC = 0.09	(kg/kg.BW)
  VLC = 0.04	(kg/kg.BW)
  QFC = 0.09	(l/hr.QC)
  QLC = 0.25	(l/hr.QC)

  PL = 3.46
  PF = 50.0
  PT = 1.29
  PB = 40.2
  MW = 104.16	(g/mol)
  VMAX = 4.95	(mg/hr)
  KM = 0.4	(mg/l)

  TSTOP = 24.	(hr)
  LENGTH = 6.	(hr)
  CONC = 600	(ppm)
}

INDEPENDENT
{
  time FROM 0 TO 24 WITH 100
}

PLOT CV VS time

ASSIGNED
{
  VTC		(kg/kg.BW)
  VT		(l)
  VF		(l)
  VL		(l)
  QF		(l/hr)
  QL		(l/hr)
  QT		(l/hr)
  CIX		(mg/l)
  MASS		(mg)
  CI CA CX
  CV FROM 0 TO 30
}

STATE
{
  CT		(mg)
  CF		(mg)
  CL		(mg)
  AM		(mg)
  DOSE		(mg)
}

INITIAL
{
  VTC = 0.91 - VLC - VFC
  VT = VTC * BW
  VF = VFC * BW
  VL = VLC * BW
  QF = QFC * QC
  QL = QLC * QC
  QT = QC - QF - QL
  CIX = CONC * MW / 24450.
}

KINETIC rates
{
  CI = pulse(time, 0., CIX, LENGTH)
  CV = (QF * CF/PF + QL * CL/PL + QT * CT/PT) / QC
  CA = (QC * CV + QP * CI) / (QC + (QP/PB))
  CX = CA / PB
~ CA <-> CT	(QT, QT/PT)
~ CA <-> CF	(QF, QF/PF)
~ CA <-> CL	(QL, QL/PL)
~ CL ->		(VMAX/(PL*KM + CL))
~ AM <<		(VMAX*CL/(PL*KM + CL))
~ CI <-> DOSE	(QP, QP)
~ CX <-> DOSE	(QP, QP)
COMPARTMENT VT {CT}
COMPARTMENT VF {CF}
COMPARTMENT VL {CL}
}

BREAKPOINT
{
  SOLVE rates METHOD clsoda
  MASS = CL*VL + CT*VT + CF*VF + AM
}