TITLE Lotka-Volterra Predation Model
:  Simulation Resources, Inc., 2-27-92
:  Reference - Spain, Microcomputer Models in Biology,
:    Addison-Wesley, 1982, page 102ff.
:  Default output - prey and predators oscillate together, but out of phase
:    with prey ranging between 105 and 1000 and predators ranging between
:    7 and 120.  The period is approximately 28.8.

PARAMETER

{
  PREY_REPRO_RATE = 0.2         : Reproductive rate of prey
  PRED_KILL_RATE = 0.005        : Kill rate by predators
  ASSIM_FRACT = 0.15            : Fraction of killed prey assimilated by predators
  PRED_DEATH_RATE = 0.3         : Death rate of predators
}

INDEPENDENT
{
  time  FROM 0.0 TO 90.0 WITH 200
}

PLOT prey,predators VS time

STATE
{
  prey  FROM 0.0 TO 1200.0 START 1000
  predators     FROM 0.0 TO 1200.0 START 50
}

ASSIGNED
{
  prey'                 FROM -300 TO 200
  predators'    FROM -50 TO 50
}

DERIVATIVE Lotka_Volterra
{
  prey' = PREY_REPRO_RATE * prey - PRED_KILL_RATE * prey * predators
  predators' = ASSIM_FRACT * PRED_KILL_RATE * prey * predators
                                 - PRED_DEATH_RATE * predators
}

BREAKPOINT

{
  SOLVE Lotka_Volterra
}