TITLE Model of Rabbit SA Node Cell
: Demir, S.S., Clark, J.W., Murphey, C.R., and Giles, W.R.
: Am. J. Physiol. 266 (Cell Physiol. 35):C832-C852, 1994
: Units are mV uL nA sec uS mM uF
: SCoP Source file created by M. Kootsey
: Simulation Resources, Inc. and Loma Linda University
: 11/27/2000

PARAMETER
{
  Vcell = 3.497e-6		(uL)
  Vi = 1.62e-6	(uL)
  VCa = 1.62e-6 (uL)
  T = 310	(K)
  F = 96487	(C/mole)
  R = 8314.     (J/k-mole.K)
  gCaL = .02115 (uS)
  gCaT = .02521 (uS)
  gBNa = 1.60e-4 (uS)
  gBCa = 3.64e-5 (uS)
  gBK = 6.94e-5 (uS)
  gf = .01963   (uS)
  gamma = .5
  kNaCa = .00001248	(nA/nM^4)
  dNaCa = .0001	(1/mM^4)
  kmNa = 5.46	(mM)
  kmK = .621	(mM)
  INaKbar = .2192	(nA)
  ICaPbar = .02869	(nA)
  Nab = 140.	(mM)
  Kb = 5.4	(mM)
  Cab  = 2.	(mM)
  Cm = 55.e-6   (uF)
  taup = .01    (Sec)
  V0 = -49.54105	(mV)
  dL0 = 2.572773e-3
  fL0 = .9865100
  dT0 = .02012114
  fT0 = .1945111
  pa0 = .02302278
  pi0 = .3777728
  y0 = 9.227776e-02
  Nai0 = 9.701621	(mM)
  Ki0 = 140.7347	(mM)
  PHI_C0 = .1411678
  PHI_TC0 = 7.331396e-02
  PHI_TMgC0 = .7618549
  PHI_TMgM0 = .2097049
  Cai0 = .0003787018	(mM)
  Caup0 = 16.95311	(mM)
  Carel0 = 16.85024	(mM)
  F10 = .1133251
  F20 = 7.594214e-4
  F30 = .8859153
  PHI_Calse0 = .9528726
  Nac0 = 139.9988       (mM)
  Kc0 = 5.389014        (mM)
  Cac0 = 2.004740       (mM)
  m0 = .2501130
  h10 = 1.386897e-3
  h20 = 2.065463e-3
  alphaup = .08	(nA)
  kcyca = .00005	(mM)
  ksrca = 22.	(mM)
  kxcs = .9
  alpharel = .5	(nA/mM)
  krel = .004	(mM)
  Mgi = 2.5	(mM)
  PNa = .00344  (uL/sec)
}

INDEPENDENT
{
  time FROM 0 TO 1 WITH 500	(sec)
}

PLOT V VS time

ASSIGNED
{
  gK betaup FRT F2RT Vc Vup Vrel ENa EK ECa
  alpham betam taum mbar alphah1 betah1 tauh1 h1bar tauh2 h2bar
  alphadL betadL taudL dLbar alphafL betafL taufL fLbar
  alphadT betadT taudT dTbar alphafT betafT taufT fTbar dprime
  alphapi betapi pabar taupa
  gfNa gfK
  ICa ybar tauy
  IBNa IBCa IBK
  Irel  FROM 0 TO .6
  Itr   FROM 0 TO .6
  Iup   FROM 0 TO .6
  F_C F_TC F_TMgC PHI_B
  K1 K2 r_act r_inact 
  IK FROM -.6 TO .2
  ICaL FROM -.6 TO .2
  If FROM -.015 TO .002
  IfNa IfK
  INa FROM -.015 TO .002
  ICaT FROM -.015 TO .002
  INaK FROM -.1 TO .06
  ICaP FROM -.1 TO .06
  INaCa FROM -.1 TO .06
  IB FROM -.1 TO .06
  Id FROM -.6 TO .2
  V' FROM -4000 TO 10000 (mV)
}

STATE
{
  V FROM -80 TO 40	(mV)
  m
  h1
  h2
  dL
  fL
  dT
  fT
  pa
  pi
  Nai
  Nac
  Ki
  Kc
  PHI_C
  PHI_TC
  PHI_TMgC
  PHI_TMgM
  PHI_Calse
  Cai FROM 0 TO .0035    (mM)
  Cac
  y
  Caup
  Carel
  F1
  F2
  F3
}

INITIAL
{
  Vup = .01166 * VCa
  Vrel = .001296 * VCa
  Vc = 0.136 * Vcell
  gK = 6.93e-3 * pow(Kb, .59)
  FRT = F / (R * T)
  F2RT = F * FRT
  betaup = kxcs * alphaup
  gfNa = 0.34375 * gf
  gfK = 0.65625 * gf
}

DERIVATIVE rates
{
: Sodium current
  Nacoeff(V)
  ENa = 26.71 * log(Nac / Nai)
  m' = (mbar - m) / taum
  h1' = (h1bar - h1) / tauh1
  h2' = (h2bar - h2) / tauh2
  INa = PNa * m * m * m * h1 * h2 * Nac * F2RT * V *
	(exp((V - ENa) * FRT) - 1.) / (exp(V * FRT) - 1.)

: Calcium currents
  Cacoeff(V)
  ECa = 13.35 * log(Cac / Cai)
  dL' = (dLbar - dL) / taudL
  fL' = (fLbar - fL) / taufL
  dT' = (dTbar - dT) / taudT
  fT' = (fTbar - fT) / taufT
  ICaL = gCaL * (dL * fL + .095 * dprime) * (V - 46.4)
  ICaT = gCaT * dT * fT * (V - 45.)
  ICa = ICaL + ICaT

: Potassium current
  Kcoeff(V)
  EK = 26.71 * log(Kc / Ki)
  pa' = (pabar - pa) / taupa
  pi' = alphapi * (1. - pi) - betapi * pi
  IK = gK * pa * pi * (V - EK)

: Pump and exchange currents
  INaK = INaKbar * pow(Nai / (Nai + kmNa), 3.) *
	pow(Kc / (Kc + kmK), 2.) * 1.6 / (1.5 + exp(-(V + 60.) / 40.))
  ICaP = ICaPbar * Cai / (Cai + .0004)
  INaCa = kNaCa * (pow(Nai,3.) * Cac  * exp(.03743 * V * gamma) -
	pow(Nac,3.) * Cai * exp(.03743 * V * (gamma - 1.))) /
	(1. + dNaCa * (Cai * pow(Nac,3.) + Cac  * pow(Nai,3.)))

: Background currents
  IBNa = gBNa * (V - ENa)
  IBCa = gBCa * (V - ECa)
  IBK =  gBK  * (V - EK)
  IB = IBNa + IBCa

: Slow inward current
  ycoeff(V)
  y' = (ybar - y) / tauy
  IfNa = gfNa * y * y * (V - 75.)
  IfK = gfK * y * y * (V + 85.)
  If = IfNa + IfK

: Intracellular concentrations, buffer equations, and SR
  Nai' = (- 3. * (INaK + INaCa) - IBNa - IfNa - INa) / (F * Vi)
  Ki' = (2. * INaK - IK - IfK - IBK) / (F * Vi)
  PHI_C' = 1.29E5 * Cai * (1. - PHI_C) - 307. * PHI_C
  PHI_TC' = 5.05E4 * Cai * (1. - PHI_TC) - 252. * PHI_TC
  PHI_TMgC' = 1.29E5 * Cai * (1. - PHI_TMgC - PHI_TMgM) - 4.25 * PHI_TMgC
  PHI_TMgM' = 1290. * Mgi * (1. - PHI_TMgC - PHI_TMgM) - 429. * PHI_TMgM
  F_C = .09 * PHI_C'
  F_TC = .031 * PHI_TC'
  F_TMgC = .062 * PHI_TMgC'
  PHI_B = F_C + F_TC + F_TMgC
  K1 = kcyca * kxcs / ksrca
  K2 = Cai + Caup * K1 + kcyca * kxcs + kcyca
  r_act = 240. * exp((V - 40.) / 12.5) + 240. * pow(Cai/(Cai + krel), 4.)
  r_inact = 40. + 400. * pow(Cai / (Cai + krel), 4.)
  PHI_Calse' = 770. * Carel * (1. - PHI_Calse) - 641. * PHI_Calse
  Irel = alpharel * pow(F2 / (F2 + .25), 2.) * Carel
  Itr = (Caup - Carel) * 2. * F * Vup / .06418
  Iup = (alphaup * Cai - betaup * Caup * K1) / K2
  Cai' = (2. * INaCa - ICa - ICaP - IBCa - Iup + Irel) / (2. * VCa * F)
	- PHI_B
  Caup' = (Iup - Itr) / (2. * Vup * F)
  Carel' = (Itr - Irel) / (2. * Vrel * F) - 11.48 * PHI_Calse
  F1' = .96 * F3 - r_act * F1
  F2' = r_act * F1 - r_inact * F2
  F3' = r_inact * F2 - .96 * F3

: Cleft space equations
  Nac' = (Nab - Nac)/taup + (INa + 3.*INaCa + 3.*INaK + IBNa + IfNa)
		/(F * Vc)
  Kc' = (Kb - Kc)/taup + (-2.*INaK + IK + IfK + IBK)/(F * Vc)
  Cac' = (Cab - Cac)/taup + (ICaL + ICaT - 2.*INaCa + ICaP + IBCa)
                /(2.*F*Vc)

: Membrane voltage
  Id = INa + ICaT + ICaL + IK + If + IB + INaK + INaCa + ICaP
  V' = - Id / Cm
}

BREAKPOINT
{
  SOLVE rates METHOD clsoda
}

PROCEDURE Nacoeff(vv)
{
  alpham = - 824. * (vv + 51.9) / (exp(-(vv + 51.9) / 8.9) - 1.)
  betam = 32960. * exp(-(vv + 51.9) / 8.9)
  taum = .000015 + 1. / (alpham + betam)
  mbar = alpham / (alpham + betam)
  alphah1 = 165. * exp(-(vv + 101.3) / 12.6)
  betah1 = 12360. / (320. * exp(-(vv + 101.3) / 12.6) + 1.)
  tauh1 = 1. / (alphah1 + betah1)
  h1bar = alphah1 * tauh1
  tauh2 = 20. * tauh1
  h2bar = h1bar
}

PROCEDURE Cacoeff(vv)
{
  alphadL = - 28.39 * (vv + 35.) / (exp(-(vv+35.) / 2.5) - 1.) -
	84.9 * vv / (exp(-.208 * vv) - 1.)
  betadL = 11.43 * (vv - 5.) / (exp(.4 * (vv - 5.)) - 1.)
  taudL = 1. / (alphadL + betadL)
  dLbar = 1. / (1. + exp(-(vv + 14.1) / 6.))
  dprime = dLbar
  alphafL = 3.75 * (vv + 28.) / (exp((vv + 28.) / 4.) - 1.)
  betafL = 30. / (1. + exp(-(vv + 28.) / 4.))
  taufL = 1. / (alphafL + betafL)
  fLbar = 1. / (1. + exp((vv + 30.) / 5.))
  alphadT = 1068. * exp((vv + 26.3) / 30.)
  betadT = 1068. * exp(-(vv + 26.3) / 30.)
  taudT = 1. / (alphadT + betadT)
  dTbar = 1. / (1. + exp(-(vv + 26.3) / 6.))
  alphafT = 15.3 * exp(-(vv + 61.7) / 83.3)
  betafT = 15 * exp((vv + 61.7) / 15.38)
  taufT = 1. / (alphafT + betafT)
  fTbar = 1. / (1. + exp((vv + 61.7) / 5.6))
}

PROCEDURE Kcoeff(vv)
{
  alphapi = 100. * exp(-.0183 * vv)
  betapi = 656. * exp(.00942 * vv)
  pabar = 1. / (1. + exp(-(vv + 5.1) / 7.4))
  taupa = 1. / (17. * exp(.0398 * vv) + 2.11 * exp(-.0510 * vv))
}

PROCEDURE ycoeff(vv)
{
  ybar = 1. / (1. + exp((vv + 72.2) / 9.))
  tauy = 1. / (1.6483 * exp(-(vv + 54.06) / 24.33) + 14.01055 /
	(.7 + exp(-(vv + 60.) / 5.5)))
}